GTAG - Downloads - CLEO Scripts - Fire Grenade

{$CLEO}

{
0@ Flame Base Dummy Object
1@ Flame
3@ Flame State

4@ Temp
5@ Temp
6@ Temp
7@ Temp
8@ Temp
9@ Temp

10@ Throw Power

30@ Cheat String
31@ Cheat String+4
32@ Timer
}

0039: 0@ == 0
else_jump @FireMayhem

:Begin
0006: 30@ = -229908
0006: 31@ = -229907
wait 1000

:FireBall
wait 150
if and
0038: &0(30@,1i) == 0x42414C4C
0038: &0(31@,1i) == 0x46495245
else_jump @FireBall
03E5: show_text_box "CHEAT1"
0247: load_model 3106
0247: load_model 3065
04ED: load_animation "GRENADE"

:Fire8Ball_Load
wait 0
if and
04EE: animation "GRENADE" loaded
0248: model 3106 available
0248: model 3065 available
else_jump @Fire8Ball_Load
0006: 3@ = 10
0107: 0@ = create_object 3106 at 0.0 0.0 0.0
0249: release_model 3106
066D: 1@ = attach_particle "molotov_flame" to_object 0@ with_offset 0.0 0.0 0.0 type 2
070A: AS_actor $PLAYER_ACTOR attach_to_object 0@ offset 0.06 0.04 0 on_bone 6 16 perform_animation "NULL" IFP_file "NULL" time 1
09E8: 2@ = actor $PLAYER_ACTOR active_interior
01B9: set_actor $PLAYER_ACTOR armed_weapon_to 0
07CC: set_player 0 button_15 0
0881: set_player 0 able_to_shoot_weapons 0
0992: set_player 0 weapons_scrollable 0
0004: &0(30@,1i) = 0x00414C4C
0039: 2@ == 1
else_jump @AltHideObject
0566: link_object 0@ to_interior 2
jump @FireLit

:AltHideObject
0566: link_object 0@ to_interior 1

:FireLit
wait 0
if or
8038: not &0(30@,1i) == 0x42414C4C
8038: not &0(31@,1i) == 0x46495245
else_jump @End
8039: not 3@ == 10
else_jump @RelightFlame
0819: 4@ = actor $PLAYER_ACTOR distance_from_ground
if and
0A0C: player 0 on_jetpack
00E1: player 0 pressed_key 15
0023: 2.0 > 4@
then
0792: disembark_instantly_actor $PLAYER_ACTOR
end

:BlowFlame
06AC: 4@ = actor $PLAYER_ACTOR movement_speed
if and
044B: actor $PLAYER_ACTOR on_foot
0021: 4@ > 5.0
else_jump @FlameNotBlown
0039: 3@ == 0
else_jump @RelightFlame
0006: 3@ = 1
064E: stop_particle 1@
jump @RelightFlame

:FlameNotBlown
0039: 3@ == 1
else_jump @WetFlame
0006: 3@ = 10

:WetFlame
//04AD: actor $PLAYER_ACTOR in_water
04E7: object 0@ in_water
else_jump @FlameNotWet
0039: 3@ == 0
else_jump @RelightFlame
0006: 3@ = 2
064E: stop_particle 1@
01BB: store_object 0@ position_to 4@ 5@ 6@
0098: 7@ = random_float
0098: 8@ = random_float
0098: 9@ = random_float
095C: create_smoke_at 4@ 5@ 6@ velocity 7@ 8@ 9@ RGBA 1.0 1.0 1.0 0.6 size 0.1 last_factor 0.2
jump @RelightFlame

:FlameNotWet
0039: 3@ == 2
else_jump @ThrowFire
0006: 3@ = 10

:ThrowFire
00E1: player 0 pressed_key 17
else_jump @RelightFlame
gosub @ThrowFireBall
jump @RelightFlame

:RelightFlame
0039: 3@ == 10
else_jump @FireLit
064C: make_particle 1@ visible
01BB: store_object 0@ position_to 4@ 5@ 6@
08EB: create_sparks_at 4@ 5@ 6@ velocity_direction 0.0 0.0 -0.4 density 5
0006: 32@ = 0
0006: 3@ = 0
jump @FireLit

:End
0004: &0(30@,1i) = 0x00414C4C
0650: destroy_particle 1@
0108: destroy_object 0@
03E5: show_text_box "CHEAT8"
04EF: release_animation "GRENADE"
07CC: set_player 0 button_15 1
0992: set_player 0 weapons_scrollable 1
0881: set_player 1 able_to_shoot_weapons 0
jump @FireBall

:ThrowFireBall
//01B4: set_player 0 can_move 0
0006: 3@ = 10
0006: 32@ = 0
064E: stop_particle 1@
0812: AS_actor $PLAYER_ACTOR perform_animation "WEAPON_start_throw" IFP "GRENADE" rate 4.0 loopA 0 lockX 1 lockY 1 lockF 1 time -1

:ThrowingFireBall
00E1: player 0 pressed_key 17
else_jump @ThrowIt
wait 0
0613: 10@ = actor $PLAYER_ACTOR animation "WEAPON_start_throw" time
0023: 0.9 > 10@
else_jump @ThrowIt
jump @ThrowingFireBall

:ThrowIt
0021: 10@ > 0.7
else_jump @ThrowItUnderarm
0812: AS_actor $PLAYER_ACTOR perform_animation "WEAPON_throw" IFP "GRENADE" rate 4.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1
jump @ThrowSpark

:ThrowItUnderarm
0812: AS_actor $PLAYER_ACTOR perform_animation "WEAPON_throwu" IFP "GRENADE" rate 4.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1

:ThrowSpark
066E: 11@ = create_particle "Flame" attached_to_object 0@ with_offset 0.0 0.0 0.0 rotation 0.0 0.0 180.0 type 2
064C: make_particle 11@ visible

:Throwing
wait 0
0611: actor $PLAYER_ACTOR performing_animation "WEAPON_throw"
else_jump @ThrowingUnderarm
0613: 9@ = actor $PLAYER_ACTOR animation "WEAPON_throw" time
jump @LetGo

:ThrowingUnderarm
0613: 9@ = actor $PLAYER_ACTOR animation "WEAPON_throwu" time

:LetGo
0021: 9@ > 0.3
else_jump @Throwing
000B: 10@ += 0.2
//01B4: set_player 0 can_move 1
0650: destroy_particle 11@
01BB: store_object 0@ position_to 7@ 8@ 9@
0107: 12@ = create_object 3065 at 7@ 8@ 9@
066E: 20@ = create_particle "fire_bike" attached_to_object 12@ with_offset 0.0 0.0 0.0 rotation 0.0 0.0 180.0 type 1
064C: make_particle 20@ visible
0750: set_object 12@ visibility 0
0392: make_object 12@ moveable 1
04D9: object 12@ set_scripted_collision_check 1
0906: set_object 12@ mass_to 0.0001
//0908: set_object 12@ turn_mass_to 0.0001
//0400: store_coords_to 4@ 5@ 6@ from_object 12@ with_offset 0.0 30.0 6.0
04C4: store_coords_to 4@ 5@ 6@ from_actor $PLAYER_ACTOR with_offset 0.0 40.0 6.0
0063: 4@ -= 7@
0063: 5@ -= 8@
0063: 6@ -= 9@
006B: 4@ *= 10@
006B: 5@ *= 10@
0381: throw_object 12@ velocity_in_direction 4@ 5@ 6@
0A92: create_custom_thread "fireball.cs" 12@ 20@
while true
if and
0611: actor $PLAYER_ACTOR performing_animation "WEAPON_throw"
0611: actor $PLAYER_ACTOR performing_animation "WEAPON_throwu"
jf break
wait 0
end
wait 800
return

:FireMayhem
0006: 32@ = 0
0006: 33@ = 0
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 1 CP 0 MP 0
while 001B: 8000 > 32@
01BB: store_object 0@ position_to 2@ 3@ 4@
04DA: has_object 0@ collided
else_jump @FireRoar
break

:FireRoar
0019: 33@ > 200
else_jump @FireRoar_2
0650: destroy_particle 5@
066E: 5@ = create_particle "fire_med" attached_to_object 0@ with_offset 0.0 0.0 0.0 rotation 0.0 0.0 180.0 type 1
064C: make_particle 5@ visible

:FireRoar_2
0039: 15@ == 0
else_jump @FireContinue
0006: 15@ = 1
0650: destroy_particle 1@
066E: 1@ = create_particle "fire_large" attached_to_object 0@ with_offset 0.0 0.0 0.0 rotation 0.0 0.0 180.0 type 1
064C: make_particle 1@ visible
//0565: create_soundless_explosion_at 2@ 3@ 4@ type 3

:FireContinue
wait 0
end
02CF: 14@ = create_fire_at 2@ 3@ 4@ propagation 1 size 3
0828: unknown_fires_stuff 6
0986: unknown_fires_stuff
02CE: 4@ = ground_z_at 2@ 3@ 4@
020C: create_explosion_with_radius 1 at 2@ 3@ 4@
0650: destroy_particle 1@
0650: destroy_particle 5@
0108: destroy_object 0@
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0
0A93: end_custom_thread